home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / mint / lib / mntc6846.zoo / patch / sftol.s < prev    next >
Encoding:
Text File  |  1994-11-14  |  3.0 KB  |  86 lines
  1.  ! C68 4 byte floating point => 32 bit integer conversion routines
  2.  !-----------------------------------------------------------------------------
  3.  ! ported to 68000 by Kai-Uwe Bloem, 12/89
  4.  !  #1  original author: Peter S. Housel 6/12/89,6/14/89
  5.  !  #2  replaced shifts by swap if possible for speed increase -kub-, 01/90
  6.  !  #3  Added wrapper routine to provide C68 IEEE compatibility
  7.  !                                             Dave & Keith Walker     02/92
  8.  !  #4    Changed entry/exit code for C68 v4.3 compatibility
  9.  !    Removed ACK entry points                    09/93
  10.  !-----------------------------------------------------------------------------
  11.  
  12.        .sect .text
  13.  
  14.        .define .Xsftol
  15.  
  16.     .extern    __huge_val
  17.     .extern    .overflow
  18.  
  19. BIAS4  =       0x7F - 1
  20.  
  21. !----------------------------------------
  22. !      sp      Return address
  23. !      sp+4    address of float/double
  24. !----------------------------------------
  25. .Xsftol:
  26.        move.l  4(sp),a0        ! address of value
  27.        move.w  (a0),d0         ! extract exp
  28.        move.w  d0,d2           ! extract sign
  29.        lsr.w   #7,d0           ! shift down 7
  30.        and.w   #0x0ff,d0       ! kill sign bit
  31.  
  32.        cmp.w   #BIAS4,d0       ! check exponent
  33.        blt     zer4            ! strictly fractional, no integer part ?
  34.        cmp.w   #BIAS4+32,d0    ! is it too big to fit in a 32-bit integer ?
  35.        bgt     toobig
  36.  
  37.        move.l  (a0),d1
  38.        and.l   #0x7fffff,d1    ! remove exponent from mantissa
  39.        or.l    #0x800000,d1    ! restore implied leading "1"
  40.  
  41.        sub.w   #BIAS4+24,d0    ! adjust exponent
  42.        bgt     2f              ! shift up
  43.        beq     3f              ! no shift
  44.  
  45.        cmp.w   #-8,d0          ! replace far shifts by swap
  46.        bgt     1f
  47.        clr.w   d1              ! shift fast, 16 bits
  48.        swap    d1
  49.        add.w   #16,d0          ! account for swap
  50.        bgt     2f
  51.        beq     3f
  52.  
  53. 1:     lsr.l   #1,d1           ! shift down to align radix point;
  54.        add.w   #1,d0           ! extra bits fall off the end (no rounding)
  55.        blt     1b              ! shifted all the way down yet ?
  56.        bra     3f
  57.  
  58. 2:     add.l   d1,d1           ! shift up to align radix point
  59.        sub.w   #1,d0
  60.        bgt     2b
  61.        bra     3f
  62. zer4:
  63.        clr.l   d1              ! make the whole thing zero
  64.  
  65. 3:     move.l  d1,d0           ! put integer into register
  66.        cmp.l   #0x80000000,d0  ! -2147483648 is a nasty evil special case
  67.        bne     6f
  68.        tst.w   d2              ! this had better be -2^31 and not 2^31
  69.        bpl     toobig
  70.        bra     8f
  71. 6:     tst.l   d0              ! sign bit set ? (i.e. too big)
  72.        bmi     toobig
  73.        tst.w   d2              ! is it negative ?
  74.        bpl     8f
  75.        neg.l   d0              ! negate
  76.  
  77. 8:    move.l    (sp)+,a1    ! get return address
  78.     add.l    #4,sp        ! remove parameter from stack
  79.     jmp    (a1)        ! return to caller
  80.  
  81. toobig:
  82.     jsr    .overflow    ! Default overflow handling routine
  83.     jsr    .setmaxmin    ! If control returned, set LONG_MAX/LONG_MIN
  84.     bra    8b        ! .., and exit backa to user
  85.  
  86.